用VBS实现的批量gb2312转utf-8,支持拖动

复制代码 代码如下:

'/*=========================================================================

' * Intro       拖动所有要转换的gb2312编码文件到这个文件上，程序会将它们自动转换为utf-8编码文件

' * FileName    GB2312.To.UTF-8.vbs

' * Author      yongfa365

' * Version     v1.0

' * WEB         http://www.yongfa365.com

' * Email       yongfa365[at]qq.com 

' * LastModify  2007-10-04 10:42:53

' *==========================================================================*/

Set objArgs = WScript.Arguments

If objArgs.Count>0 Then

    If MsgBox("本程序仅支持GB2312到UTF-8的转换"&vbCrLf&"如果您所拖动的文件里有别的格式的文件请点“取消”", vbOKCancel + vbExclamation + vbDefaultButton2, "郑重提醒!!!") = vbOK Then

        For I = 0 To objArgs.Count - 1

            FileUrl = objArgs(I)

            Call WriteToFile(FileUrl, ReadFile(FileUrl, "gb2312"), "utf-8")

        Next

    End If

Else

    MsgBox "请将您要转换的“gb2312文件”拖到这个文件上"&vbCrLf&"程序会将它们自动转换为utf-8文件", vbInformation, "柳永法温馨提示："

End If

'-------------------------------------------------

'函数名称:ReadFile

'作用:利用AdoDb.Stream对象来读取各种格式的文本文件

'----------------------------------------------------

Function ReadFile(FileUrl, CharSet)

    Dim Str

    Set stm = CreateObject("Adodb.Stream")

    stm.Type = 2

    stm.mode = 3

    stm.charset = CharSet

    stm.Open

    stm.loadfromfile FileUrl

    Str = stm.readtext

    stm.Close

    Set stm = Nothing

    ReadFile = Str

End Function

'-------------------------------------------------

'函数名称:WriteToFile

'作用:利用AdoDb.Stream对象来写入各种格式的文本文件

'参数:FileUrl-文件相对路径;Str-文件内容;CharSet-编码格式(utf-8,gb2312.....)

'----------------------------------------------------

Function WriteToFile (FileUrl, Str, CharSet)

    Set stm = CreateObject("Adodb.Stream")

    stm.Type = 2

    stm.mode = 3

    stm.charset = CharSet

    stm.Open

    stm.WriteText Str

    stm.SaveToFile FileUrl, 2

    stm.flush

    stm.Close

    Set stm = Nothing

End Function


您可能感兴趣的文章:

• 将字符串转换成gb2312或者utf-8编码的参数(js版)
• php实现utf-8和GB2312编码相互转换函数代码
• UTF-8 GBK UTF8 GB2312 之间的区别和关系介绍
• PHP字符编码问题之GB2312 VS UTF-8解决方法
• VBS实现GB2312,UTF-8,Unicode,BIG5编码转换工具
• PHP 解决utf-8和gb2312编码转换问题
• unicode utf-8 gb18030 gb2312 gbk各种编码对比
• ASP中Utf-8与Gb2312编码转换乱码问题的解决方法 页面编码声明
• MSSQL转MYSQL，gb2312转utf-8无乱码解决方法
• PHP iconv 解决utf-8和gb2312编码转换问题
• ASP UTF-8页面乱码+GB2312转UTF-8 +生成UTF-8格式的文件(编码)
• 用javascript实现gb2312转utf-8的脚本
• [转]ASP实现关键词获取(各搜索引擎,GB2312及UTF-8)
• UTF-8转GB2312函数
• utf-8编码转换成gb2312
• 将编码从GB2312转成UTF-8的方法汇总(从前台、程序、数据库)

本文由 华域联盟 原创撰写：华域联盟 » 用VBS实现的批量gb2312转utf-8,支持拖动

转载请保留出处和原文链接：https://www.cnhackhy.com/14894.htm