vbs版的解密base64加密的脚本

复制代码 代码如下:

Function fDecode(sStringToDecode) 

'This function will decode a Base64 encoded string and returns the decoded string. 

'This becomes usefull when attempting to hide passwords from prying eyes. 

Const CharList = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/" 

Dim iDataLength, sOutputString, iGroupInitialCharacter 

sStringToDecode = Replace(Replace(Replace(sStringToDecode, vbCrLf, ""), vbTab, ""), " ", "") 

iDataLength = Len(sStringToDecode) 

If iDataLength Mod 4 <> 0 Then 

fDecode = "Bad string passed to fDecode() function." 

Exit Function 

End If 

For iGroupInitialCharacter = 1 To iDataLength Step 4 

Dim iDataByteCount, iCharacterCounter, sCharacter, iData, iGroup, sPreliminaryOutString 

iDataByteCount = 3 

iGroup = 0 

   For iCharacterCounter = 0 To 3 

    sCharacter = Mid(sStringToDecode, iGroupInitialCharacter + iCharacterCounter, 1) 

     If sCharacter = "=" Then 

      iDataByteCount = iDataByteCount - 1 

      iData = 0 

     Else 

      iData = InStr(1, CharList, sCharacter, 0) - 1 

       If iData = -1 Then 

        fDecode = "Bad string passed to fDecode() function." 

        Exit Function 

       End If 

     End If 

    iGroup = 64 * iGroup + iData 

   Next 

iGroup = Hex(iGroup) 

iGroup = String(6 - Len(iGroup), "0") & iGroup 

sPreliminaryOutString = Chr(CByte("&H" & Mid(iGroup, 1, 2))) & Chr(CByte("&H" & Mid(iGroup, 3, 2))) & Chr(CByte("&H" & Mid(iGroup, 5, 2))) 

sOutputString = sOutputString & Left(sPreliminaryOutString, iDataByteCount) 

Next 

fDecode = sOutputString 

End Function

vbs代码打包

您可能感兴趣的文章:

• 关于base64加密/解密
• 关于加密解密 Base64 and URL and Hex Encoding and Decoding
• Js base64 加密解密介绍
• python字符串加密解密的三种方法分享(base64 win32com)
• php使用base64加密解密图片示例分享
• java常用工具类之DES和Base64加密解密类
• php中base64_decode与base64_encode加密解密函数实例
• C#实现基于Base64的加密解密类实例
• C#编写的Base64加密和解密类

本文由 华域联盟 原创撰写：华域联盟 » vbs版的解密base64加密的脚本

转载请保留出处和原文链接：https://www.cnhackhy.com/14953.htm